# Maintainer: Oscar Wallberg <oscar.wallberg@outlook.com>
pkgname=trackma
pkgver=0.10.3
pkgrel=1
_anime_relations_commit=4a5549a43d14ffb268694c6821667fb47578e146
pkgdesc="A lightweight program for managing lists on media tracking websites"
arch=('any')
url="https://z411.github.io/trackma/"
license=('GPL-3.0-or-later')
depends=('python')
makedepends=(
  'desktop-file-utils'
  'python-build'
  'python-installer'
  'python-poetry-core'
  'python-wheel'
)
optdepends=(
  'gtk3: GTK frontend'
  'lsof: polling tracker'
  'python-cairo: GTK frontend'
  'python-gobject: GTK frontend'
  'python-jeepney: MPRIS media recognition tracker'
  'python-pillow: thumbnail images for GUI frontends'
  'python-pyinotify: instant media recognition tracker'
  'python-pypresence: Discord rich presence integration'
  'python-pyqt6: Qt frontend'
  'python-urwid: curses frontend'
)
conflicts=('trackma-git')
source=(
  "${pkgname}-${pkgver}.tar.gz::https://github.com/z411/${pkgname}/archive/refs/tags/v${pkgver}.tar.gz"
  "anime-relations-${_anime_relations_commit}.tar.gz::https://github.com/erengy/anime-relations/archive/${_anime_relations_commit}.tar.gz"
  "${pkgname}-curses.desktop"
  "${pkgname}-gtk.desktop"
  "${pkgname}-qt.desktop"
)
sha256sums=('ff15982555b377e63c36fc8d8964d210cdd79564ea633ecce22ca1796dcac41f'
            '1bd746482867391d1f332e5924e8ffec26ab024591b956bc54c5259ee75c6cf0'
            '8265fca3f9d18f2c97f4f578bb2fcc9bed8837845c2b7dccc2f020150ddf70c1'
            '564f219f64991a51fcfe3afebfe43198cb035aa3b20e1ef566c64ad2c55f09f5'
            '583c65eed9f25f13961eab62f1c7490cfea78e07c3747002d8edebef62a10564')

prepare() {
  cd "${pkgname}-${pkgver}"

  rm -rf "trackma/data/anime-relations"
  cp -a "${srcdir}/anime-relations-${_anime_relations_commit}" "trackma/data/anime-relations"
}

build() {
  cd "${pkgname}-${pkgver}"

  python -m build --wheel --no-isolation
}

package() {
  cd "${pkgname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl
  rm -f "${pkgdir}"/usr/lib/python*/site-packages/trackma/trackma.kdev4

  install -Dm644 "trackma/data/icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  desktop-file-install --dir="${pkgdir}/usr/share/applications" \
    "${srcdir}/${pkgname}-curses.desktop" \
    "${srcdir}/${pkgname}-gtk.desktop" \
    "${srcdir}/${pkgname}-qt.desktop"
}
