# Maintainer: Oscar Wallberg <oscar.wallberg@outlook.com>

pkgname=mpv-git
pkgver=0.41.0.r774.g2339eb7276
pkgrel=1
pkgdesc='a free, open source, and cross-platform media player (git version)'
arch=('x86_64')
license=('GPL-2.0-or-later AND LGPL-2.1-or-later')
url='https://mpv.io/'
depends=(
  'alsa-lib'
  'desktop-file-utils'
  'ffmpeg'
  'glibc'
  'hicolor-icon-theme'
  'jack'
  'lcms2'
  'libarchive'
  'libass'
  'libbluray'
  'libcdio'
  'libcdio-paranoia'
  'libdisplay-info'
  'libdrm'
  'libdvdnav'
  'libdvdread'
  'libegl'
  'libgl'
  'libglvnd'
  'libjpeg-turbo'
  'libplacebo'
  'libpipewire'
  'libpulse'
  'libsixel'
  'libva'
  'libvdpau'
  'libx11'
  'libxext'
  'libxkbcommon'
  'libxpresent'
  'libxrandr'
  'libxss'
  'libxv'
  'luajit'
  'mesa'
  'mujs'
  'rubberband'
  'uchardet'
  'vapoursynth'
  'vulkan-icd-loader'
  'wayland'
  'zlib'
)
makedepends=(
  'ffnvcodec-headers'
  'git'
  'ladspa'
  'meson'
  'python-docutils'
  'vulkan-headers'
  'wayland-protocols'
)
provides=('mpv' 'libmpv.so')
conflicts=('mpv')
options=('!emptydirs')
source=('mpv::git+https://github.com/mpv-player/mpv.git')
sha256sums=('SKIP')

pkgver() {
  cd mpv
  git describe --long --tags --match 'v[0-9]*.[0-9]*.[0-9]*' \
      | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  arch-meson mpv build \
    --auto-features=auto \
    -Dbuild-date=false \
    -Dtests=true \
    -Dcaca=disabled \
    -Dcdda=enabled \
    -Ddrm=enabled \
    -Ddvbin=enabled \
    -Ddvdnav=enabled \
    -Dlibarchive=enabled
  meson compile -C build
}

check() {
  meson test -C build
}

package() {
  depends+=(
    'libasound.so' 'libavcodec.so' 'libavdevice.so' 'libavfilter.so'
    'libavformat.so' 'libavutil.so' 'libdisplay-info.so' 'libswresample.so'
    'libswscale.so' 'libjack.so' 'liblcms2.so' 'libarchive.so' 'libass.so'
    'libbluray.so' 'libjpeg.so' 'libplacebo.so' 'libpulse.so' 'libva.so'
    'libva-drm.so' 'libva-wayland.so' 'libva-x11.so' 'libxkbcommon.so'
    'librubberband.so'
  )

  meson install -C build --destdir "$pkgdir"

  sed -i -e '/Requires.private/d' -e '/Libs.private/d' \
    "$pkgdir"/usr/lib/pkgconfig/mpv.pc

  install -m0644 mpv/TOOLS/{umpv,mpv_identify.sh,stats-conv.py,idet.sh,lua/*} \
    -D -t "$pkgdir"/usr/share/mpv/scripts
}
