# Maintainer: Oscar Wallberg <oscar.wallberg@outlook.com>
pkgname=claude-code
pkgver=2.1.193
pkgrel=1
pkgdesc="Use Claude, Anthropic's AI assistant, right from your terminal"
arch=('x86_64')
url="https://claude.ai/code"
license=('LicenseRef-proprietary')
options=('!strip')
provides=('claude')
conflicts=('claude')

source=("manifest.json::https://downloads.claude.ai/claude-code-releases/${pkgver}/manifest.json"
        "claude::https://downloads.claude.ai/claude-code-releases/${pkgver}/linux-x64/claude"
        "claude.sh")
sha256sums=('SKIP'
            'SKIP'
            'd4f14ff492a181c59f42b32cf97d8682801d77ae7be0a96f5730c22755dd16c0')

check() {
    local manifest
    manifest=$(< manifest.json)
    [[ $manifest =~ \"linux-x64\"[^}]*\"checksum\":[[:space:]]*\"([a-f0-9]{64})\" ]]
    local expected="${BASH_REMATCH[1]}"
    local actual
    actual=$(sha256sum claude | cut -d' ' -f1)
    if [[ "$actual" != "$expected" ]]; then
        error "Binary checksum mismatch: got $actual, manifest has $expected"
        return 1
    fi
}

package() {
    install -Dm755 claude "${pkgdir}/usr/lib/claude-code/claude"
    install -Dm755 claude.sh "${pkgdir}/usr/bin/claude"
}
