diff --git a/init.lua b/init.lua
index 7476ff9..d0d0da0 100644
--- a/init.lua
+++ b/init.lua
@@ -63,6 +63,7 @@ require("ts").setup({
     "https://github.com/tree-sitter/tree-sitter-html",
     "https://github.com/tree-sitter/tree-sitter-javascript",
     "https://github.com/tree-sitter/tree-sitter-json",
+    "https://github.com/flurie/tree-sitter-jq",
     "https://github.com/tree-sitter-grammars/tree-sitter-luadoc",
     {
         src = "https://github.com/TheLeoP/tree-sitter-mustache",
diff --git a/queries/bash/injections.scm b/queries/bash/injections.scm
index 5b7e06b..d9dabe5 100644
--- a/queries/bash/injections.scm
+++ b/queries/bash/injections.scm
@@ -65,6 +65,53 @@
   (#set! injection.include-children)
   (#set! injection.language "printf"))
 
+; jq 'filter'
+((command
+  name: (command_name) @_command
+  .
+  argument: [
+    (string)
+    (raw_string)
+  ] @injection.content)
+  (#eq? @_command "jq")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "jq"))
+
+; jq -r 'filter'
+((command
+  name: (command_name) @_command
+  argument: (word) @_arg
+  .
+  argument: [
+    (string)
+    (raw_string)
+  ] @injection.content)
+  (#eq? @_command "jq")
+  (#any-of? @_arg "-c" "-e" "-r" "-M" "-R" "-s" "-n")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "jq"))
+
+; jq --arg name value 'filter'
+((command
+  name: (command_name) @_command
+  argument: (word) @_arg
+  .
+  (_)
+  .
+  (_)
+  .
+  argument: [
+    (string)
+    (raw_string)
+  ] @injection.content)
+  (#eq? @_command "jq")
+  (#any-of? @_arg "--arg" "--argjson" "--slurpfile" "--rawfile")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "jq"))
+
 ((command
   name: (command_name) @_command
   .
diff --git a/queries/jq/highlights.scm b/queries/jq/highlights.scm
new file mode 100644
index 0000000..5d6050f
--- /dev/null
+++ b/queries/jq/highlights.scm
@@ -0,0 +1,158 @@
+; Variables
+(variable) @variable
+
+((variable) @constant.builtin
+  (#eq? @constant.builtin "$ENV"))
+
+((variable) @constant.macro
+  (#eq? @constant.macro "$__loc__"))
+
+; Properties
+(index
+  (identifier) @property)
+
+; Labels
+(query
+  label: (variable) @label)
+
+(query
+  break_statement: (variable) @label)
+
+; Literals
+(number) @number
+
+(string) @string
+
+[
+  "true"
+  "false"
+] @boolean
+
+"null" @type.builtin
+
+; Interpolation
+[
+  "\\("
+  ")"
+] @character.special
+
+; Format
+(format) @attribute
+
+; Functions
+(funcdef
+  (identifier) @function)
+
+(funcdefargs
+  (identifier) @variable.parameter)
+
+[
+  "reduce"
+  "foreach"
+] @function.builtin
+
+((funcname) @function.call
+  .
+  "(")
+
+; jq -n 'builtins | map(split("/")[0]) | unique | .[]'
+((funcname) @function.builtin
+  (#any-of? @function.builtin
+    "IN" "INDEX" "JOIN" "abs" "acos" "acosh" "add" "all" "any" "arrays" "ascii_downcase"
+    "ascii_upcase" "asin" "asinh" "atan" "atan2" "atanh" "booleans" "bsearch" "builtins" "capture"
+    "cbrt" "ceil" "combinations" "contains" "copysign" "cos" "cosh" "debug" "del" "delpaths" "drem"
+    "empty" "endswith" "env" "erf" "erfc" "error" "exp" "exp10" "exp2" "explode" "expm1" "fabs"
+    "fdim" "finites" "first" "flatten" "floor" "fma" "fmax" "fmin" "fmod" "format" "frexp"
+    "from_entries" "fromdate" "fromdateiso8601" "fromjson" "fromstream" "gamma" "get_jq_origin"
+    "get_prog_origin" "get_search_list" "getpath" "gmtime" "group_by" "gsub" "halt" "halt_error"
+    "has" "hypot" "implode" "in" "index" "indices" "infinite" "input" "input_filename"
+    "input_line_number" "inputs" "inside" "isempty" "isfinite" "isinfinite" "isnan" "isnormal"
+    "iterables" "j0" "j1" "jn" "join" "keys" "keys_unsorted" "last" "ldexp" "length" "lgamma"
+    "lgamma_r" "limit" "localtime" "log" "log10" "log1p" "log2" "logb" "ltrimstr" "map" "map_values"
+    "match" "max" "max_by" "min" "min_by" "mktime" "modf" "modulemeta" "nan" "nearbyint" "nextafter"
+    "nexttoward" "normals" "not" "now" "nth" "nulls" "numbers" "objects" "path" "paths" "pick" "pow"
+    "pow10" "range" "recurse" "remainder" "repeat" "reverse" "rindex" "rint" "round" "rtrimstr"
+    "scalars" "scalb" "scalbln" "scan" "select" "setpath" "significand" "sin" "sinh" "sort"
+    "sort_by" "split" "splits" "sqrt" "startswith" "stderr" "strflocaltime" "strftime" "strings"
+    "strptime" "sub" "tan" "tanh" "test" "tgamma" "to_entries" "todate" "todateiso8601" "tojson"
+    "tonumber" "tostream" "tostring" "transpose" "trunc" "truncate_stream" "type" "unique"
+    "unique_by" "until" "utf8bytelength" "values" "walk" "while" "with_entries" "y0" "y1" "yn"))
+
+; Keywords
+[
+  "def"
+  "as"
+  "label"
+  "module"
+  "break"
+] @keyword
+
+[
+  "import"
+  "include"
+] @keyword.import
+
+[
+  "if"
+  "then"
+  "elif"
+  "else"
+  "end"
+] @keyword.conditional
+
+[
+  "try"
+  "catch"
+] @keyword.exception
+
+[
+  "or"
+  "and"
+] @keyword.operator
+
+; Operators
+[
+  "."
+  "=="
+  "!="
+  ">"
+  ">="
+  "<="
+  "<"
+  "="
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  "+="
+  "-="
+  "*="
+  "/="
+  "%="
+  "//="
+  "|"
+  "?"
+  "//"
+  "?//"
+  (recurse) ; ".."
+] @operator
+
+; Punctuation
+[
+  ";"
+  ","
+  ":"
+] @punctuation.delimiter
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+  "("
+  ")"
+] @punctuation.bracket
+
+; Comments
+(comment) @comment @spell
diff --git a/queries/jq/injections.scm b/queries/jq/injections.scm
new file mode 100644
index 0000000..f8a7a35
--- /dev/null
+++ b/queries/jq/injections.scm
@@ -0,0 +1,23 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+; test(val)
+(query
+  ((funcname) @_function
+    (#any-of? @_function "test" "match" "capture" "scan" "split" "splits" "sub" "gsub"))
+  (args
+    .
+    (query
+      (string) @injection.content
+      (#set! injection.language "regex"))))
+
+; test(regex; flags)
+(query
+  ((funcname) @_function
+    (#any-of? @_function "test" "match" "capture" "scan" "split" "splits" "sub" "gsub"))
+  (args
+    .
+    (args
+      (query
+        (string) @injection.content
+        (#set! injection.language "regex")))))